» » » » » Cara Menghitung Jumlah Abjad Dan Kata

Cara Menghitung Jumlah Abjad Dan Kata

, , , Edit
Rumus Excel Menghitung Jumlah Huruf dan Kata Cara Menghitung Jumlah Huruf dan Kata
Masih tentang rumus yang bekerja pada data text. Kali ini kita akan membahas bagaimana cara menghitung jumlah abjad , karakter atau kata tertentu dalam sebuah text atau string. Menghitung jumlah bab text tertentu sanggup dilakukan dengan satu formula saja, baik itu menghitung text dalam satu sel saja , maupun menghitung text yang terdapat dalam range atau kumpulan sel .


Secara garis besar,  struktur pembahasan berguru excel kali ini mencakup:

Cara Menghitung Jumlah Huruf dan Kata Pada Excel


  • Menghitung jumlah karakter atau kata dalam satu sel.
    • Menghitung abjad atau karakter tunggal
      • Dengan membedakan abjad besar/kecil
      • Tanpa Membedakan abjad besar/kecil
    • Menghitung jumlah kata 
      • Dengan membedakan abjad besar/kecil
      • Tanpa membedakan abjad besar/kecil
  • Menghitung jumlah karakter atau kata dalam kumpulan sel.
    • Menghitung abjad atau karakter tunggal
      • Dengan membedakan abjad besar/kecil
      • Tanpa Membedakan abjad besar/kecil
    • Menghitung jumlah kata 
      • Dengan membedakan abjad besar/kecil
      • Tanpa membedakan abjad besar/kecil





Menghitung jumlah karakter atau kata dalam satu sel.

Anggaplah kita mempunyai text yang akan dihitung jumlah huruf, karakter atau kata dalam text tersebut.

Text     :
Saya anak yang baik. Anak-anak lain suka saya
Lokasi :
Sel B2

Maka rumus yang sanggup dipakai sanggup dilihat dalam tabel pola di bawah ini.

No
Menghitung
Hasil
Formula
1
Semua Karakter
45
=LEN(B2)
2
Huruf "a"
13
=LEN(B2)-LEN(SUBSTITUTE(B2,"a",""))
3
Huruf "A"
1
=LEN(B2)-LEN(SUBSTITUTE(B2,"A",""))
4
Huruf "a" dan "A"
14
=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))
5
Kata "anak"
2
=(LEN(B2)-LEN(SUBSTITUTE(B2,"anak","")))/LEN("anak")
6
Kata "Anak"
1
=(LEN(B2)-LEN(SUBSTITUTE(B2,"Anak","")))/LEN("Anak")
7
Kata "anak" dan "Anak"
3
=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),"anak","")))/LEN("anak")

Bisa diperhatikan kembali pada pola diatas, bahwa secara umum fungsi yang diperlukan untuk keperluan perhitungan karakter atau kata yaitu LEN dan SUBSTITUTE  serta UPPER atau LOWER
  • Fungsi LEN mempunyai kegunaan untuk menghitung jumlah karakter dalam text.
  • Fungsi SUBSTITUTE mempunyai kegunaan untuk mengganti bab text  atau karakter tertentu dengan text atau karakter lainnya. Fungsi ini bersifat Case Sensitive, sehingga menganggap beda antara abjad kecil dengan kapital (contoh : abjad “a” dan abjad “A”). 
  • Fungsi UPPER mempunyai kegunaan untuk merubah semua abjad dalam text menjadi abjad kapital semuanya
  • Fungsi LOWER mempunyai kegunaan untuk merubah semua abjad dalam text menjadi abjad kecil semuanya


Cara Kerja Rumus Excel Untuk Menghitung Jumlah Huruf Dan Karakter Tertentu.


Menghitung karakter atau abjad tunggal dengan membedakan abjad besar/kecil

Contoh: Menghitung jumlah abjad "a" dalam text yang berada dalam sel B2

=LEN(B2)-LEN(SUBSTITUTE(B2,"a",""))

  • Fungsi SUBSTITUTE akan menukar karakter atau abjad yang dihitung dengan text kosong 
  • Fungsi LEN menghitung jumlah karakter awal dan jumlah karakter sehabis di SUBSTITUTE
  • Operasi matematika pengurangan menghitung selisih atara jumlah karakter awal dan jumlah karakter sehabis di-SUBSTITUTE
  • Selisih itulah yang merupakan jumlah karakter yang dicari.

Menghitung karakter atau abjad tunggal tanpa membedakan abjad besar/kecil

Contoh: Menghitung jumlah abjad "a" dan "A" dalam text yang berada dalam sel B2

=LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"A",""))

  • Fungsi UPPER akan merubah semua abjad dalam text menjadi abjad besar semua
  • Fungsi SUBSTITUTE akan menukar karakter atau abjad yang dihitung (A) dengan text kosong 
  • Fungsi LEN menghitung jumlah karakter awal dan jumlah karakter sehabis di SUBSTITUTE
  • Operasi matematika pengurangan menghitung selisih atara jumlah karakter awal dan jumlah karakter sehabis di-SUBSTITUTE
  • Selisih itulah yang merupakan jumlah karakter yang dicari.
  • Dengan konsep yang serupa, kita juga sanggup mengganti fungsi UPPER menjadi LOWER
    • =LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),"a",""))

Menghitung jumlah kata dengan membedakan abjad besar/kecil






Contoh: Menghitung jumlah abjad "Anak" dalam text yang berada dalam sel B2

=(LEN(B2)-LEN(SUBSTITUTE(B2,"Anak","")))/LEN("Anak")

  • Fungsi SUBSTITUTE akan menukar kata "Anak" dengan text kosong 
  • Fungsi LEN menghitung jumlah karakter awal dan jumlah karakter sehabis di SUBSTITUTE
  • Operasi matematika pengurangan menghitung selisih atara jumlah karakter awal dan jumlah karakter sehabis di-SUBSTITUTE
  • Selisihnya lalu dibagi dengan banyaknya karakter kata "Anak"
  • Hasil pembagian itulah yang merupakan hasil kesannya yaitu jumlah kata "Anak"

Menghitung jumlah kata Tanpa membedakan abjad besar/kecil

Contoh: Menghitung jumlah abjad "Anak" dan "Anak"  dalam text yang berada dalam sel B2

=(LEN(B2)-LEN(SUBSTITUTE(LOWER(B2),"anak","")))/LEN("anak")

  • Fungsi LOWER akan merubah semua abjad dalam text menjadi abjad kecil semua
  • Fungsi SUBSTITUTE akan menukar kata "anak" dengan text kosong 
  • Fungsi LEN menghitung jumlah karakter awal dan jumlah karakter sehabis di SUBSTITUTE
  • Operasi matematika pengurangan menghitung selisih atara jumlah karakter awal dan jumlah karakter sehabis di-SUBSTITUTE
  • Selisihnya lalu dibagi dengan banyaknya karakter kata "anak"
  • Hasil pembagian itulah yang merupakan hasil kesannya yaitu jumlah kata "Anak" dan "anak"
  • Dengan konsep yang serupa, kita juga sanggup mengganti fungsi LOWER menjadi UPPER
    • =(LEN(B2)-LEN(SUBSTITUTE(UPPER(B2),"ANAK","")))/LEN("ANAK")


Menghitung jumlah karakter atau kata dalam kumpulan sel.


Anggaplah text yang akan kita hitung yaitu menyerupai berikut:

Text    :
Nama saya Saleh
Saya anak yang baik
Anak-anak lain suka saya
Apalagi anak komplek
Lokasi :
Sel B2:B5

Maka rumus untuk menghitung kehadiran karakter atau kata dalam kumpulan sel B2:B5 sanggup diformulasikan menyerupai pola dalam tabel di bawah ini:

No
Menghitung
Jumlah
Formula
1
Semua Karakter
78
=SUMPRODUCT(LEN(B2:B5))
2
Huruf "a"
22
=SUMPRODUCT(LEN(B2:B5)-LEN(SUBSTITUTE(B2:B5,"a","")))
3
Huruf "A"
2
=SUMPRODUCT(LEN(B2:B5)-LEN(SUBSTITUTE(B2:B5,"A","")))
4
Huruf "a" dan "A"
24
=SUMPRODUCT(LEN(B2:B5)-LEN(SUBSTITUTE(UPPER(B2:B5),"A","")))
5
Kata "anak"
3
=SUMPRODUCT((LEN(B2:B5)-LEN(SUBSTITUTE(B2:B5,"anak","")))/LEN("anak"))
6
Kata "Anak"
1
=SUMPRODUCT((LEN(B2:B5)-LEN(SUBSTITUTE(B2:B5,"Anak","")))/LEN("Anak"))
7
Kata "anak" dan "Anak"
4
=SUMPRODUCT((LEN(B2:B5)-LEN(SUBSTITUTE(LOWER(B2:B5),"anak","")))/LEN("anak"))

Dapat kita perhatikan dari pola diatas, bahwa perbedaan fundamental dari rumus yang dipakai untuk menghitung banyaknya abjad atau kata dalam kumpulan sel dibandingkan dalam satu sel saja yaitu adanya penggunaan fungsi SUMPRODUCT.  

Cara kerja rumus untuk menghitung abjad dan kata pada kumpulan sel sesungguhnya hampir sama saja dengan cara kerja rumus untuk menghitung abjad dan kata pada satu sel.

Yang membedakannya yaitu alasannya yaitu bekerja pada array atau kumpulan sel maka perlu ditambahkan fungsi untuk menjumlahkan hasil dari masing-masing sel. Tambahan fungsi yang dipakai di sini yaitu SUMPRODUCT.

Sebagai alternative lainnya, kita juga sanggup menggunakakan rumus array CSE. Cukup ganti SUMPRODUCT menjadi SUM, dan jangan lupa untuk tekan CTR+SHIFT+ENTER sehabis mengetikan rumusnya.


No
Menghitung
Jumlah
Formula
1
Semua Karakter
78
{=SUM(LEN(B2:B5))}
2
Huruf "a"
22
{=SUM(LEN(B2:B5)-LEN(SUBSTITUTE(B2:B5,"a","")))}
3
Huruf "A"
2
{=SUM(LEN(B2:B5)-LEN(SUBSTITUTE(B2:B5,"A","")))}
4
Huruf "a" dan "A"
24
{=SUM(LEN(B2:B5)-LEN(SUBSTITUTE(UPPER(B2:B5),"A","")))}
5
Kata "anak"
3
{=SUM((LEN(B2:B5)-LEN(SUBSTITUTE(B2:B5,"anak","")))/LEN("anak"))}
6
Kata "Anak"
1
{=SUM((LEN(B2:B5)-LEN(SUBSTITUTE(B2:B5,"Anak","")))/LEN("Anak"))}
7
Kata "anak" dan "Anak"
4
{=SUM((LEN(B2:B5)-LEN(SUBSTITUTE(LOWER(B2:B5),"anak","")))/LEN("anak"))}


Ringkasan:
Cara menghitung banyaknya abjad atau kata tertentu pada data excel sanggup dilakukan memakai rumus kombinasi fungsi LEN,SUBSTITUTE,UPPER/LOWER serta operasi matematika pengurangan dan pembagian. Jika text yang dihitung terdapat pada kumpulan sel, maka cukup tambahkan fungsi SUMPRODUCT pada rumus kombinasi tadi. Sebagai alternative, fungsi SUMPRODUCT juga sanggup diganti fungsi SUM dalam bentuk rumus array.

Demikian biar bermanfaat.
Salam.. 😉

Baca juga tutorial berguru excel lainnya:

0 Response to "Cara Menghitung Jumlah Abjad Dan Kata"

Posting Komentar

Langganan: Posting Komentar (Atom)